英飞凌功率半导体器件级别

使用 infineon 官方提供的 Spice 模型时，发现存在多个级别。基本级别 L0 的 MOSFET 不具有夹断特性，始终线性增长。

本文主要记录不同级别模型的区别，及相关使用方法。

英飞凌的器件模型介绍

英飞凌提供 4 种不同级别的功率半导体模型。这些模型以 _Lx 为后缀，且 x∈{0,1,2,3}x\in\{0,1,2,3\} 。

其中 L0 是一个简化的模型，不考虑温度等较复杂的细节。主要用于提高仿真速度或在一些不支持高级功能的 Spice 仿真软件中使用。

而 L1,L2,L3 则考虑了更多细节，包括温度与封装等参量对器件电性能的影响。

级别 引脚 使用情景
L0 G, D, S 一般电气模拟/整个应用电路。
L1 G, D, S 瞬态、开关损耗和效率分析。器件在整个温度范围内的行为。
L2 G, D, S, Tj, Tcase 与 L1 相同，但具有单独的设备温度。不支持此模型，因为它被 L3 模型覆盖。
L3 G, D, S, Tj, Tcase 自热效应、热流建模，包括应用热模型。

Tj 结温。Tcase 壳温。

L0 级别

如果仿真重点非常关注速度，那么 L0 级 PSpice 模型是大多数应用仿真的最佳选择。该结构是基本上由标准元件组成的等效子电路。这些模型也可用于其他类似 Spice 的模拟器，这些模拟器不支持 PSpice 特定语法（如函数语句）。

封装电路参数

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
* 定义一个四端口子电路，四个端口分别为漏极、栅极、源极和开尔文源极
.SUBCKT IPQC65R029CFD7_L0 drain gate source source_sense

.PARAM act=35.699999999999996

* 创建一个 cool_techg0a 子电路实例，传递参数 act
X1 dd g s cool_techg0a PARAMS: a={act}
Lg gate g1 8.72E-09
Ld drain dd 1.72E-09
Ls source s1 2.59E-09
Lss source_sense sk1 4.95E-09
Rs s1 s 3.48E-04
Rss sk1 s 4.16E-02
Rg g1 g 3.8
.ENDS IPQC65R029CFD7_L0

核心电路参数

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
* 定义子电路，漏极，栅极和源极并具有参数 a
.SUBCKT cool_tech0a d1 g2 s2 PARAMS: a=1

* 参数定义
** MOSFET主模型参数
.PARAM MOS_KP_A=5.35			; MOS 跨导参数基值
.PARAM MOS_VTO={4.726*1.07}		; 阈值电压
.PARAM MOS_THETA={0.0+0}		; 沟道迁移率退化系数
.PARAM MOS_ETA={0.0+0.00}		; DIBL效应参数

** 漂移区电阻参数
.PARAM MOS_RdA={0.69*1.0}		; 漏极漂移区电阻基值
.PARAM MOS_TC_RD={14m*0.95}	; 漂移区电阻温度系数

** 输出特性修正MOS
.PARAM MOSR_KPR_A={9.166*1.35}	; 辅助MOS跨导
.PARAM MOSR_VTOR={-1*0.9}		; 辅助MOS阈值
.PARAM MOSR_LAMBDAR={0.15*1.2}	; 沟道长度调制

** 雪崩二极管参数
.PARAM Dbt_BV={650*1.0}			; 雪崩击穿
.PARAM Dbt_M={0.9*1.0}			; 结电容指数
.PARAM Dbt_CJ0_A={0.343n*1.0}	; 零偏结电容
.PARAM Dbt_VJ={0.5*1.0}			; 结势

** 体二极管参数
.PARAM DBODY_IS_A={116000p*1}	; 反向饱和电流
.PARAM DBODY_N={2.2*0.8}		; 发射系数
.PARAM DBODY_RRS={5u*1}			; 二极管内部串联电阻
.PARAM DBODY_EG={1.12*1}		; 硅禁带宽度
.PARAM DBODY_TT=250.023n		; 反向恢复时间
.PARAM DBODY_RSA={120m*2.55}	; 体二极管外部串联电阻
.PARAM DBODY_RS_TC={3m*0.01}	; 温度系数

** 栅源电容参数
.PARAM DGD_M={0.55*1.0}		; Miller 电容指数 Drain-Gate Dynamic Capacitance Multiplier
.PARAM DGD_VJ={0.5*1.0}		; 结势

** 电容参数
.PARAM CAP_Cox_Ab={0.023n*0.82} ；基准Miller电容
.PARAM CAP_Cgs_Ab={0.24n*0.83} ; 基准Cgs
.PARAM CAP_Cds1_Ab={1.71p*0.88} ; 基准Cds

** 面积缩放
.PARAM MOS_KP={MOS_KP_A*a}			; 跨导按面积增大
.PARAM MOS_Rd={MOS_RdA/a}			; 电阻按面积减小
.PARAM MOSR_KPR={MOSR_KPR_A*a}		; 辅助MOS跨导
.PARAM Dbt_CJ0={Dbt_CJ0_A*a}		; 结电容
.PARAM DBODY_IS={DBODY_IS_A*a}		; 二极管反向饱和电流
.PARAM DBODY_RS={DBODY_RSA/a}		; 体二极管外部串联电阻
.PARAM CAP_Cox_b={CAP_Cox_Ab*a}		; 基准Miller电容
.PARAM CAP_Cgs_b={CAP_Cgs_Ab*a}		; 基准Cgs电容
.PARAM CAP_Cds1_b={CAP_Cds1_Ab*a}	; 基准Cds电容

* 主 MOS 定义
M1 d2 g2 s2 s2 DMOS L=1u W=1u	; 定义一个叫做 M1 的 MOS
								；Drain结点:d2, Gate结点:g2, Source结点:s2, Body结点:s2
								；使用器件模型为 DMOS 
								；沟道长1u,宽度1u

.MODEL DMOS NMOS ( KP= {MOS_KP} VTO={MOS_VTO} THETA={MOS_THETA} VMAX=1.5e5 ETA={MOS_ETA} LEVEL=3); 定义

* 漂移区电阻定义
Rd d2 d1a {MOS_Rd} TC1={MOS_TC_RD}
.MODEL MVDR NMOS (KP={MOSR_KPR} VTO={MOSR_VTOR} LAMBDA={MOSR_LAMBDAR})

* 辅助MOS定义
Mr d1 d2a d1a d1a MVDR W=1u L=1u

* 防止悬空
Rx d2a d1a 1m

* 输出电容
Cds1 s2 d2 {CAP_Cds1_b}

* 漏源结电容
Dbd s2 d2 Dbt
.MODEL Dbt D(BV={Dbt_BV} M={Dbt_M} CJO={Dbt_CJ0} VJ={Dbt_VJ} T_ABS=25)

* MOS 体二极管
Dbody s2 21 DBODY
.MODEL DBODY D(IS={DBODY_IS} N={DBODY_N} RS={DBODY_RRS} EG={DBODY_EG} TT={DBODY_TT})
Rdiode d1 21 {DBODY_RS} TC1={DBODY_RS_TC}

* 理想开关模型
.MODEL sw NMOS(VTO=0 KP=10 LEVEL=1 T_ABS=25)
Maux g2 c a a sw
Maux2 b d g2 g2 sw

* 受控源
Eaux c a d2 g2 1
Eaux2 d g2 d2 g2 -1

* Miller电容主体
Cox b d2 {10*CAP_Cox_b}
.MODEL DGD D(M={DGD_M} CJO={CAP_Cox_b} VJ={DGD_VJ} T_ABS=25)
Rpar b d2 100Meg
Dgd a d2 DGD
Rpar2 d2 a 100Meg
Cgs g2 s2 {CAP_Cgs_b}

.ENDS cool_tech0a

L1 级别 (恒定温度)

L1 级模型假定整个电路在瞬态仿真期间器件温度恒定。因为该级模型引入了温度参量，因此必须在分析设置中给出工作温度。

此外，对电容的电压依赖性进行了非常精确的建模。

L2 级别 (动态温度)

2 级模型使用户能够为电路中的各个部件定义不同的温度。通过将电压源连接到结温引脚 Tj ，可以在瞬态计算期间动态更改这些温度。如果未连接 Tj 引脚，则使用默认温度 27 °C 进行计算。

结温引脚将电压(V)转换为温度(℃)。

2 级模型不适用于 CoolMOS™ 器件，因为 3 级模型类型完全涵盖了 2 级的所有功能。

L3 级别 (电热计算)

为了能够动态计算自热，电气模型与 3 级模型中的器件热模型相结合。为此，需要永久确定晶体管中的电流功耗，并将与该功率成比例的电流馈入热等效网络。 Tj 节点的电压包含有关与时间相关的结温的信息，而该信息又直接作用于与温度相关的电气模型。英飞凌的 3 级型号符号（五个引脚）如下图所示。

Tj 与 Tcase
  • Tj 引脚主要用于对结温的监控，一般悬空即可。但是当模拟结温的非稳态情况时，可以使用一个小电容(初值为起始温度)对地短接。
  • Tcase 为器件壳温。通过阻容网络对地来进行热仿真，下图为典型应用电路。R1 描述了器件到散热系统的热阻，C1 为散热系统自身的热容，R2 为散热系统对外界的热阻， Vth 则描述了外界环境温度。

参考文献

  1. Introduction to Infineon’s Simulation Models: Power MOSFETs